Copy all tags from source to target in Studio 2014

;QuickPlace hack for tags
^@:: ; you will probably want to change this keyboard shortcut; for example ^!+T:: would set it to ctrl-alt-shift-T
send {escape} ; closes autosuggest if open
send ^, ; opens quickplace (standard shortcut)
loop, 10 ; only looks for quickplace for a second or two
{
ImageSearch, QuickX, QuickY, 1,1,%A_ScreenWidth%,%A_ScreenHeight%, *10 %A_ScriptDir%\quickplaceactivated.png ; waits for quickplace to be active and finds out where it is on the screen
if ErrorLevel
{
quickplacefound := 0
sleep, 50
}
else
{
quickplacefound := 1
break
}
}
if quickplacefound = 0 ; show message if quickplace not found and ends
{
ToolTip, QuickPlace not found!, 700, 500
Sleep, 3000
ToolTip
return
}
;The following sets the area to search for tags; this is much faster than searching the entire screen
QuickX := QuickX - 10
QuickY := QuickY - 10
QuickXend := QuickX + 40
QuickYend := QuickY + 250
loop, 10 ; if the script messes up and quickplace is not open it will go down a maximum of 10 lines. This also means the script will not work if there are more than 10 non-tag placeables to go through
{
ImageSearch, , , %QuickX%,%QuickY%,%QuickXend%,%QuickYend%, *40 %A_ScriptDir%\tagselected.png ; checks if a tag is selected
if ErrorLevel ; goes down and loops if a tag is not selected
{
tagfound := 0
send {down}
sleep, 50 ; need to wait for the display to update, otherwise a tag may be skipped
}
else ; breaks loop if a tag is selected
{
tagfound := 1
break
}
}
if tagfound = 0
{
ToolTip, Tag not found!, %QuickY%, %QuickX% ; Shows an error if a tag was not found. The location of the tooltip indicates the top left of the area searched; if this is off, then there was an error when searching for quickplace
Sleep, 3000
ToolTip
}
if tagfound = 1
{
send {enter} ; inserts the found tag
}
return